Download the Eye4Software GPS Toolkit fully functional 30 day trial version for free
	Browse through the Eye4Software GPS Toolkit manual

Albers Equal Area Conic Projection

The Albers equal-area conic projection, is a map projection that uses two standard parallels to reduce some of the distortion of a projection with one standard parallel. Although neither shape nor linear scale is truly correct, the distortion of these properties is minimized in the region between the standard parallels. This projection is best suited for land masses extending in an east-to-west orientation rather than those lying north to south. It is used by the USGS for maps showing the conterminous United States (48 states) or large areas of the United States, as well as for many thematic maps.

Required Parameters

To convert Albers Equal Conic Area coordinates, the following parameters have to be set:

• False Northing;
• False Easting;
• Standard Parallel 1;
• Standard Parallel 2;
• Latitude Of Center;
• Longitude Of Center;

Eye4Software GPS Toolkit

The following code sample (VBScript) shows how to use the Albers Equal Area Conic Projection with the Eye4Software GPS Toolkit:

' demo_albers.vbs
'
' This demo translates lat/lon coordinates (WGS84) to Australian Albers ( GDA94 ) using
' Albers Equal Area Conic Area projection
' 
' This demo specifies a map grid based on the Alberts Equal Area Conicsprojection, by setting all geodetic parameters. 
'
' If you want to convert using one of the 4000 grids that are included in the component,
' you should have a look at the demo_gridsimple.vbs demo (recommended for users with less or no experience in geodesy).

Option Explicit

Dim objDatumSrc, objDatumDst, objGridSrc, objGridDst, objProjection, objConstants

Set objDatumSrc		= CreateObject ( "Eye4Software.GpsDatumParameters" )
Set objDatumDst		= CreateObject ( "Eye4Software.GpsDatumParameters" )
Set objGridSrc 		= CreateObject ( "Eye4Software.GpsGridParameters" )
Set objGridDst 		= CreateObject ( "Eye4Software.GpsGridParameters" )
Set objProjection   	= CreateObject ( "Eye4Software.GpsProjection" )
Set objConstants 	= CreateObject ( "Eye4Software.GpsConstants" )

WScript.Echo "Eye4Software GPS Toolkit " & objProjection.Version & " - Albers Equal Area Conic Projection Demo" 
WScript.Echo

' // Start of parameters part //

' Set Source Datum: WGS84
objDatumSrc.Axis		= 6378137.000
objDatumSrc.Flattening		= 298.257223563

' Set Source GridL: Latitude/Longitude
objGridSrc.Projection		= 0
objGridSrc.Datum		= objDatumSrc

' Set Destination Datum: GDA94
objDatumDst.Axis		= 6378137.000
objDatumDst.Flattening		= 298.257222101

' Set destination grid: Australian Alberts
objGridDst.Projection		= objConstants.GPS_PROJECTION_ALBERSEQUALAREA
objGridDst.Datum		= objDatumDst
objGridDst.OriginLatitude	= 0.0
objGridDst.OriginLongitude	= 132.0
objGridDst.ParallelNorth	= -18.0
objGridDst.ParallelSouth	= -36.0

' // End of parameters part //

' Set Source coordinate
objProjection.Latitude		= -27.50000
objProjection.Longitude		= 131.50000

WScript.Echo "Convert from WGS84 to Australian Albers (GDA94) using Albers Equal Area Conic projection"
WScript.Echo
WScript.Echo "Latitude    = " & objProjection.Latitude
WScript.Echo "Longitude   = " & objProjection.Longitude
WScript.Echo

' Perform the transformation
objProjection.TransformGrid objGridSrc, objGridDst

' Return the result
WScript.Echo "Result: " & objProjection.LastError & " (" & objProjection.LastErrorDescription & ")"
WScript.Echo
If ( objProjection.LastError = 0 ) Then
	WScript.Echo "Northing    = " & objProjection.Northing
	WScript.Echo "Easting     = " & objProjection.Easting
End If

WScript.Echo "Ready."

Click here to show a list of all supported map projections.